Hello everyone ,

I'm coding a download system with ASP. I want to hide the URLs of the files and I want to allow only my members to download the files. I'm using these codes ;

Set FSO = Server.CreateObject("Scripting.FileSystemObject")
Set XFile = FSO.GetFile(Path)
Set TS=FSO.OpenTextFile(XFile)
Response.ContentType="application/unknown"
Response.AddHeader "Content-Disposition", "attachment; filename=" & FileName
Response.BinaryWrite TS.readall & ""
TS.Close
Set TS=Nothing
Set XFile=Nothing
Set FSO=Nothing

' FileName points the system path of the file.

But members download the files in a few seconds but there are some errors. For example 30mb. file downloads as a 1Kb.

I cannot understand reason of this error. What can I do or do you know another secure download system that permit unknown visitors to download files?

and the problems are occured just while downloading the video files (asf,wmw,mpeg). there are no problem while downloadind zip files.

It will be the use of opentextfile, ideally you should be using be using a stream object

Working bit from the download script I use. The filename in this is constructed from the file path of the document calling the sub

Sub DownloadFile(strPath)
  Dim strAbsFile
  Dim strFileExtension
  Dim objFSO
  Dim objFile
  Dim objStream
  dim strFileName
  dim FileName
  
  ' set absolute file location
  strAbsFile = Server.MapPath(strPath)
'  response.write strAbsFile
  ' create FSO object to check if file exists and get properties
  Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
  ' check to see if the file exists
  If objFSO.FileExists(strAbsFile) Then
    Set objFile = objFSO.GetFile(strAbsFile)
      Response.Clear
 	  FileName = split(objFile.name,".")
	  strFileName = GetPagePath() & "." & FileName(ubound(FileName)) ' right(objFile.Name,instrrev(objFile.Name,".") - 1)'& GetSubjectFolder()
      Response.AddHeader "Content-Disposition", "attachment; filename=" & strFileName ' objFile.Name
      Response.AddHeader "Content-Length", objFile.Size
      Response.ContentType = "application/octet-stream"
      Set objStream = Server.CreateObject("ADODB.Stream")
        objStream.Open
        '-- set as binary
        objStream.Type = 1
        Response.CharSet = "UTF-8"
        '-- load into the stream the file
        objStream.LoadFromFile(strAbsFile)
        '-- send the stream in the response
        Response.BinaryWrite(objStream.Read)
        objStream.Close
      Set objStream = Nothing
    Set objFile = Nothing
  Else  'objFSO.FileExists(strAbsFile)
    Response.Clear
    Response.Write("No such file exists.")
  End If
  Set objFSO = Nothing
End Sub